Command builders

This page covers the builder path to an application command: plain objects you assemble in Skript, as an alternative to slash command and user command / message command. You're assumed to have a bot named "my-bot" logged in.

How builders work

A builder is a command object with settable properties: a name, a description, options, subcommands. It has no trigger and nothing reaches Discord until a script pushes it with update or register, the same effects a structure uses.

on guild ready:
    set {_roll} to a new slash command named "roll" with description "Roll a dice"
    set {_sides} to a new integer option named "sides" with description "How many sides"
    set min value of {_sides} to 2
    set max value of {_sides} to 100
    add {_sides} to options of {_roll}

    register the discord command {_roll} in event-guild

Unlike DiSky's entity builders elsewhere, there's no separate "build result": the effects above push the object itself, and command id of {_roll} is only set afterwards, once Discord answers.

Answering a built command

A builder-declared command has no trigger of its own, so it's answered in the generic on slash command, matched by name. Read an option with slash option "name"; an omitted optional option is not set.

on slash command:
    if used slash command is "roll":
        set {_sides} to slash option "sides"
        if {_sides} is not set:
            set {_sides} to 6
        reply with hidden "You rolled %random integer between 1 and {_sides}%"

Properties

Every builder type shares the applicationcommand properties below; slashcommand and slashoption add their own on top.

enabled for, disabled, nsfw, contexts and integration types also apply to every builder; see Command settings.

Subcommands and groups

A subcommand is a /root sub entry with its own description and options; a subcommandgroup groups several subcommands under /root group sub. A slash command has either options or subcommands (with or without groups), never both.

on guild ready:
    set {_mod} to a new slash command named "mod" with description "Moderation tools"

    set {_ban} to a new subcommand named "ban" with description "Ban a member"
    add a new user option named "target" with description "Who to ban" to options of {_ban}
    add {_ban} to subcommands of {_mod}

    set {_kick} to a new subcommand named "kick" with description "Kick a member"
    add a new user option named "target" with description "Who to kick" to options of {_kick}
    add {_kick} to subcommands of {_mod}

    register the discord command {_mod} in event-guild

/mod ban and /mod kick above match the same structure-declared shape from Slash commands; a subcommand group adds one more level: build it with a new subcommand group named ... with description ..., add subcommands to it, then add the group to subcommand groups of the command.

Mixing structures and builders

structured slash command "mod" reads a structure-declared command back as the same kind of object a builder makes: editable, and separate from the .sk file that declared it. Localize it, add an option, then push it like any other object.

on guild ready:
    set {_mod} to structured slash command "mod"
    localize the description of {_mod} in "fr" to "Outils de modération"
    register the discord command {_mod} in event-guild

A structure and a builder can also be pushed side by side, in one call: update the discord commands (all structured application commands) and {_roll} in event-guild replaces every structure-declared command and adds {_roll} in the same PUT. A structure-declared command still runs its own trigger; a builder-declared one only ever answers in the generic event. Both fire the generic event first, whichever way they were declared.

Errors you may see