Managing rules

This page covers the rules that already exist on a guild, whether a script or a moderator made them: reading them, changing them, deleting them, and the event that fires when one acts. You're assumed to have a bot named "my-bot" logged in with Manage Server, and to know the three await rules.

Reading a guild's rules

automod rules of %guild% lists every rule of a guild, and automod rule with id %string% in %guild% fetches one. DiSky keeps no AutoMod cache, so both ask Discord and both require await.

on message received seen by "my-bot":
    if discord content of event-message is "!rules":
        await set {_rules::*} to automod rules of event-guild
        loop {_rules::*}:
            reply with "%name of loop-value%: %automod trigger type of loop-value%, enabled %enabled of loop-value%"

What you get is a snapshot taken at that moment. Read a rule again after editing it to see the new state.

Editing a rule

name, enabled, exempt roles, exempt channels, automod responses and trigger config are writable on a rule. Every change is sent to Discord at once; put await in front to wait for it before the next line reads the rule again.

on message received seen by "my-bot":
    if discord content of event-message is "!pause-rules":
        await set {_rules::*} to automod rules of event-guild
        loop {_rules::*}:
            await set enabled of loop-value to false
            await add event-channel to exempt channels of loop-value

add and remove start from the rule as it was read. One add a and b to ... line sends both values together, but two separate add lines on the same snapshot each start from that snapshot, so only the second one survives: read the rule again between them.

trigger config replaces what the rule looks for. It is write-only (read the keyword, preset and mention properties instead), and the new trigger must be of the rule's kind: a keyword rule takes a keyword or pattern trigger, never a preset one.

set {_t} to a new automod keyword trigger with the keywords "newword"
await set trigger config of {_rule} to {_t}

Deleting a rule

destroy deletes a rule.

on message received seen by "my-bot":
    if discord content of event-message is "!drop-rule":
        await set {_rule} to automod rule with id "000000000000000000" in event-guild
        destroy {_rule}

When a rule fires

on automod execution fires once per response a rule takes: a rule that blocks the message and sends an alert fires it twice. The bot needs the auto_moderation_execution intent for it.

on automod execution seen by "my-bot":
    send "%event-user% triggered %automod rule id of event-automod% in %event-channel%" to console
    send "matched '%matched keyword of event-automod%' in: %automod message content of event-automod%" to console

event-automod carries what was matched. matched keyword and matched content say what set the rule off, automod message content is the whole message (empty without the message_content intent), and event-automodresponse is the response being run.

Errors you may see